#!/usr/bin/perl -w
use strict;
$|++;

use CGI qw(:all);

use Cache::FileCache;
my $cache = Cache::FileCache->new
  ({namespace => 'antirobot',
    username => 'nobody',
    default_expires_in => '10 minutes',
    auto_purge_interval => '1 hour',
   });

if (length (my $info = path_info())) { # I am the image
  my ($session) = $info =~ m{\A/([0-9a-f]+)\.png\z}i
    or do {
      warn("bad URL $info");
      print header(-status => '404 Not Found');
      exit 0;
    };

  defined(my $verify = $cache->get($session))
    or do {
      warn("Cannot find $session");
      print header(-status => '404 Not Found');
      exit 0;
    };

  ## make up an image from the verify string
  require GD;

  my $font = GD::gdGiantFont();
  my $image = GD::Image->new(2 + $font->width * length $verify,
                             2 + $font->height);
  my $background = $image->colorAllocate(0,0,0);
  ## $image->transparent($background);
  my $ink = $image->colorAllocate(255,255,255);
  $image->string($font, 1, 1, $verify, $ink);
  print header('image/png'), $image->png;
  exit 0;
}

print header,
  start_html("Vote for your favorite!"),
  h1("Vote for your favorite ice cream flavor!");

if (defined(my $verify = param('verify'))) {
  Delete('verify');
  if (defined (my $session = param('session'))) {
    Delete('session');
    if (defined (my $validate = $cache->get($session))) {
      $cache->remove($session); # one chance is all you get
      if ($validate eq $verify) { # success!
        ## would save param('flavor') here
        print h2("Thank you!"), p("Your vote has been counted."), end_html;
        exit 0;
      }
      print p("Sorry, please reenter the security string exactly as shown!");
    }
  }
}

my $verify = do {
  my @charset = grep !/[10joli]/i, 0..9, 'a'..'z', 'A'..'Z';
  join "", map { $charset[rand @charset] } 1..8;
};

my $session = do {
  require MD5;
  MD5->hexhash(MD5->hexhash(time.{}.rand().$$));
};
param('session', $session);
$cache->set($session, $verify);

print hr, startform;
print p("Your favorite ice-cream?");
print radio_group(-name => "flavor",
                  -values => [qw(None Other Chocolate Vanilla Strawberry)],
                  -default => "None",
                  -columns => 1);
print p("For security purposes, please enter",
        img({src => url()."/$session.png"}).":",
        textfield(-name => "verify"));
print hidden('session');
print br, submit, endform, hr;
print end_html;