#!/usr/bin/perl
use strict;
$|++;

use My_HTML_Filter;

## from http://www.perlmonks.org/index.pl?node_id=29281

my %PERMITTED =
  map { my($k, @v) = split; ($k, {map {$_, 1} @v}) }
  split /\n/, <<'END';
a href name target class title
b 
big 
blockquote class
br
center 
dd 
div class
dl 
dt 
em 
font size color class
h1
h2
h3 
h4 
h5 
h6 
hr
i 
li 
ol type start
p align class
pre class
small 
span class title
strike 
strong 
sub 
sup 
table width cellpadding cellspacing border bgcolor class
td width align valign colspan rowspan bgcolor height class
th colspan width align bgcolor height class
tr width align valign class
tt class
u 
ul 
END

use Test::More qw(no_plan);

my $f = My_HTML_Filter->new(\%PERMITTED) or die;
isa_ok($f, "My_HTML_Filter");

is($f->strip(qq{Hello}),
   qq{<p>Hello</p>\n},
   "basic text gets paragraphed");
is($f->strip(qq{<p><bogus>Thing}),
   qq{<p>Thing</p>\n},
   "bogons gets stripped");
is($f->strip(qq{<a href="foo">bar</a>}),
   qq{<a href="foo">bar</a>\n},
   "links are permitted");
is($f->strip(qq{<a href=foo>bar</a>}),
   qq{<a href="foo">bar</a>\n},
   "attributes get quoted");
is($f->strip(qq{<a href=foo bogus=place>bar</a>}),
   qq{<a href="foo">bar</a>\n},
   "bad attributes get stripped");
is($f->strip(qq{<p>What do <!-- comment -->you say?}),
   qq{<p>What do you say?</p>\n},
   "comments get stripped");
is($f->strip(qq{<table><tr><td>Hi!}),
   qq{<table><tr><td>Hi!</td></tr></table>\n},
   "tags get balanced");
is($f->strip(qq{<b><i>bold italic!}),
   qq{<b><i>bold italic!</i></b>\n},
   "b/i tags get balanced");
is($f->strip(qq{<b><i>bold italic!</b></i>}),
   qq{<b><i>bold italic!</i></b>\n},
   "b/i tags get nested properly");
is($f->strip(qq{<B><I>bold italic!</I></B>}),
   qq{<b><i>bold italic!</i></b>\n},
   "tags get lowercased");
is($f->strip(qq{<h1>hey</h1>one<br>two}),
   qq{<h1>hey</h1>\n<p>one<br>two</p>\n},
   "br comes out as HTML not XHTML");

use Benchmark;
my $homepage = do { open my $f, "homepage.html"; join "", <$f> };

timethese
  (-1,
   {
    strip_homepage => sub { $f->strip($homepage) }
   });