#################### LISTING ONE ####################
#!/usr/bin/env xsh
quiet;

# open --format html 'cpan.html';
open --format html 'http://www.cs.uu.nl/people/henkp/mirmon/cpan.html';

for //tr[th/a/@name = 'de']/following-sibling::* {
  if th/a/@name last;
  $url = (td[1]/a[1]/@href);
  $time = (td[3]);
  perl { $time{$url} = $time };
}

perl {
  for (values %time) {
    s{([\d.]+) days?}{$1 * 24}e
      or s{([\d.]+) hours?}{$1}
        or s{([\d.]+) minutes?}{sprintf "%.1f", $1 / 60}e
          or die "Don't understand $_";
  }

  for (sort { $time{$a} <=> $time{$b} } keys %time) {
    print "$_ => $time{$_}\n";
  }
}
#################### LISTING TWO ####################
#!/usr/bin/env perl

use HTML::TreeBuilder::XPath;
use LWP::Simple;

my $tree = HTML::TreeBuilder::XPath->new;
# $tree->parse_file('cpan.html');
$tree->parse_content(get 'http://www.cs.uu.nl/people/henkp/mirmon/cpan.html');

my %time;
for ($tree->findnodes(q{//tr[th/a/@name = 'de']/following-sibling::*})) {
  last if $_->exists(q{th/a/@name});
  my $url = $_->findvalue(q{td[1]/a[1]/@href});
  my $time = $_->findvalue(q{td[3]});
  $time{"$url"} = "$time";      # ensure stringy
}

for (values %time) {
  s{([\d.]+) days?}{$1 * 24}e
    or s{([\d.]+) hours?}{$1}
      or s{([\d.]+) minutes?}{sprintf "%.1f", $1 / 60}e
        or die "Don't understand $_";
}

for (sort { $time{$a} <=> $time{$b} } keys %time) {
  print "$_ => $time{$_}\n";
}