#!/usr/bin/perl -w
use strict;
$|++;

use HTML::Parser;

my @feet;                       # final footnote list
my @feet_index;                 # indexes into @feet

my @elements;                   # ensure nested tags match

my $parser = HTML::Parser->new
  (
   text_h => [\&text_h, "text"],
   start_h => [\&start_h, "text, tagname"],
   end_h => [\&end_h, "text, tagname"],
  );

$parser->xml_mode(1);           # keep tags case-sensitive
$parser->parse_file(\*DATA);    # prints main part to STDOUT

if (@feet) {                    # we had footnotes?
  print "<hr><table border='0' cellspacing='0' cellpadding='2'>\n";
  print "<tr><td valign='top'><sup><a name='note$_'>$_</a></sup></td>",
    "<td>$feet[$_-1]</td></tr>\n" for 1..@feet;
  print "</table>";
}

exit 0;                         # end of code

sub text_h {
  my ($text) = @_;
  if (@feet_index) {            # are we inside a footnote?
    $feet[$feet_index[-1]] .= $text;    # append to that
  } else {
    print $text;                # just show it
  }
}

sub start_h {
  my ($text, $tagname) = @_;

  ## ensure proper nesting
  push @elements, $tagname;

  if ($tagname eq "foot") {
    push @feet, "";             # the note itself
    text_h("<sup><a href='#note".@feet."'>".@feet."</a></sup>");
    push @feet_index, $#feet;   # pointer to note
    return;
  }
  
  text_h($text);                # uninteresting start tag
}

sub end_h {
  my ($text, $tagname) = @_;

  ## ensure proper nesting
  die "saw $text outside of element"
    unless @elements;
  die "saw $text nested inside <$elements[-1]>"
    unless $elements[-1] eq $tagname;
  pop @elements;

  if ($tagname eq "foot") {
    pop @feet_index;                    # no longer accumulating here
    return;
  }
  
  text_h($text);                # uninteresting end tag
}

__END__
<h2>Writing a Perl column</h2>
Writing a magazine column about Perl is a simple<foot>for some!</foot> task.
Just perform the following steps:
<ol>
<li>Think of a problem to
  solve<foot>You can ask around for help here.
  I keep an archive of "todo" ideas, and it really helps.</foot>.</li>
<li>Write the code to solve it.<foot>The code should be between 50 and 200
  lines for optimum column
  length<foot>About 10,000 characters.</foot>.</foot></li>
<li>Fret over the code for a few hours<foot>Or a few minutes.</foot>.</li>
<li>Write the column<foot>I use POD<foot>See <tt>perldoc perlpod</tt>.</foot>
  format.</foot>.</li>
<li>Show the column to a group of friends
  on IRC<foot>Usually the <tt>#perl</tt> channel.</foot>
  for a quick peer review.</li>
<li>Turn it in<foot>By email.</foot> to the editor.</li>
<li>Wait a few days for the galleys<foot>Usually a
  PDF<foot><i>Portable Document Format</i> from
  Adobe<foot>See <tt>www.adobe.com</tt> for downloads.</foot>.</foot>.</foot>
  to come back.</li>
<li>Grimace over the hacks to your lovely
prose<foot>just kidding, guys!</foot> and provide corrections to
the corrections.
</li>
<li>Wait a few months<foot>Or so it seems, since the deadline
for a April cover is usually the first week of January.</foot> for it
to "hit the stands".</li>
<li>Wave the magazine in front of your friends<foot>Or the cute girl
at the bookstore checkout counter.</foot>!</li>
</ol>